package scg.gen;
import scg.Util;
import scg.game.*;
import edu.neu.ccs.demeterf.lib.*;


PlayerID = <id> int implements Comparable(PlayerID).
Var = <id> ident implements Comparable(Var).

// Using the new ListMap, instead
// this is CSP specific !!!
Solution = <assign> ListMap(Var,Boolean).

// change: depends on protocol
ChallengeKind = All | Secret.
All = "all".
Secret = "secret".

// Challenge -> Claim
// Offered -> Proposed
Claim = ProposedClaim
          | AcceptedClaim 
// Provided means: Claim with provided instance
          | ProvidedClaim

          | SolvedClaim *s
          <key> int *s
          <claimer> PlayerID *s

	  // change: refer to Claim definition
          <pred> ProblemType *s

	  // change to quality
          <price> double *s

	  // change: link to claim set definition
          <kind> ChallengeKind "]".
         
ProposedClaim = "proposed[".

AcceptedClaim = "accepted["
                    <claimee> PlayerID.
ProvidedClaim = "provided["
                     <claimee> PlayerID *s
                     <instance> Instance.
SolvedClaim = "solved["
                  <claimee> PlayerID *s
                  <instance> Instance *s
                  <solution> Solution *s
                  <quality> double.

Transaction = ProposeTrans 
            | AcceptTrans
            | StrengthenTrans
            | ProvideTrans
            | SolveTrans "]".

ProposeTrans   = *l*t "offer[" <claimid> int *s <kind> ChallengeKind *s
                             <pred> ProblemType *s <price> double.
AcceptTrans  = *l*t "accept[" <claimid> int.

// change: protocol may use a secret instance
ProvideTrans = *l*t "provide[" <inst> Instance *s <secret> Option(Solution) *s <claimid> int.

SolveTrans   = *l*t "solve[" <sol> Solution *s <claimid> int.

// change: show strengthened claim
// is it enough to change price to quality?

StrengthenTrans = *l*t "strengthen[" <claimid> int *s <price> double.


PlayerTrans  = *l "playertrans["
               *l*t <id> PlayerID
               <ts> List(Transaction) *l
               "]".

Config = "config["
            *l*t "gamekind:" *s <gamekind> String
            *l*t "turnduration:" *s <turndur> int
            *l*t "mindecrement:" *s <mindecr> double
            *l*t "initacc:" *s <initacc> double
            *l*t "maxProposals:" *s <maxProposals> int
            *l*t "minProposals:" *s <minProposals> int
            *l*t "minPropositions:" *s <minPropositions> int
            *l*t "objective:" *s <objective> Objective
            *l*t "predicate:" *s <predicate> Predicate
            *l*t "numrounds:" *s <numrounds> int
            *l*t "profitfactor:" *s <profitFactor> double
            *l*t "otrounds:" *s <otrounds> int
            *l*t "hasSecrets:" *s <hasSecrets> boolean
            // A secretRatio must be 0 if hasSecrets is false
            // SecretRatio must be in the range [0,1]
            *l*t "secretRatio:" *s <secretRatio> double
            *l
         "]".
 
PlayerContext = "context["
                   *l*t <config> Config
                   *l*t <id> PlayerID 
                   *l*t <balance> double
                   *l*t <currentRound> int                   
                   *l*t "(" <ourProposed> List(ProposedClaim) ")"
                   *l*t "(" <theirProposed> List(ProposedClaim) ")"
                   *l*t "(" <accepted> List(AcceptedClaim) ")"
                   *l*t "(" <provided> List(ProvidedClaim) ")" 
                   *l*t "(" <solved> List(SolvedClaim) ")" 
                   *l*t <statement> Option(AccountTransactionList)
                   *l
                "]" EOF.

AccountTransactionList = "(" <accts> List(AccountTransaction) ")".
AccountTransaction = AccountAcceptTrans 
                   | AccountSolveTrans 
                   | AccountRefundTrans
                   "." *s "acceptor:" *s
                   <acceptor> int *s "offerer:" *s
                   <offerer> int *s "]".
                   
AccountAcceptTrans = "[acceptor paid" *s
                      <amount> double *s "for challenge" *s
                      <challengeId> int.
AccountSolveTrans =  "[acceptor received" *s
                      <amount> double *s "for solving" *s
                      <fsat> double *s "of challenge" *s
                      <challengeId> int.
AccountRefundTrans = "[acceptor refunded" *s
                      <amount> double *s "for challenge" *s
                      <challengeId> int.